home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Penthouse Interactive Virtual Photo Shoot 4
/
Penthouse Virtual Photo Shoot - Volume 4.iso
/
pc
/
setup
/
setup.mst
< prev
next >
Wrap
Text File
|
1995-03-11
|
14KB
|
397 lines
rem ---------------------------------------------------------------------
rem
rem SETUP.MST - MSSETUP Installation Script
rem
rem Version 1.0
rem
rem (c) 1993 San Francisco Canyon Co. All Rights Reserved.
rem
rem ---------------------------------------------------------------------
rem Required includes to interface with MSSETUP DLL's
rem -------------------------------------------------
'$INCLUDE 'setupapi.inc'
'$INCLUDE 'msdetect.inc'
rem Dialog box id's
rem ---------------
rem Note: If MSSETUP were really smart, we could use the
rem #defines in DIALOGS.HR. Instead, we must manually
rem keep them in step
rem ----------------------------------------------------
CONST DESTPATH = 300 ''Gets destination path
CONST EXITQUIT = 600 ''Exits on user request
CONST EXITSUCCESS = 700 ''Exits when install is done
CONST TOOBIG = 6300 ''Not enough space on target disk error
CONST BADPATH = 6400 ''Bad destination path error
CONST BADWINDOWS = 6500 ''Wrong Windows release
CONST EXITFAILURE = 6600 ''Exits on error
rem String id's
rem -----------
rem Note: If MSSETUP were really smart, we could use the
rem #defines in DIALOGS.HR. Instead, we must manually
rem keep them in step
rem ----------------------------------------------------
CONST STR_UTILITY = 1024 ''Utility
CONST STR_GROUP = 1025 ''Program Manager group
CONST STR_TITLE = 1026 ''Installer Title
CONST STR_MSG1 = 1027 ''Version error message part 1
CONST STR_MSG2 = 1028 ''Version error message part 2
CONST STR_WARNING = 1029 ''Warning
CONST STR_README = 1030 ''Read Me
rem Miscellaneous Constants
rem -----------------------
CONST NOLOGO = 1 ''Dummy NULL bitmap (must be 1)
CONST LOGO = 2 ''Background bitmap
CONST MOVIE = 2 ''Movie placeholder bitmap
CONST NOSPACE = 1 ''No space to complete install
CONST INSTALLOK = 2 ''Install completed OK
CONST INSTALLFAILED =3 ''Install failed for some reason
rem Global Variables
rem ----------------
GLOBAL SOURCE$ ''Source directory
GLOBAL DEST$ ''Default destination directory
GLOBAL CUIDLL$ ''User interface DLL
GLOBAL SETUPPATH$ ''Setup destination path
GLOBAL HELPPROC$ ''Help dialog procedure
GLOBAL EXTRACOSTS$ ''List of extra costs to add per drive
GLOBAL APPNEEDS$ ''Disk space costs per drive
GLOBAL SECTIONKEY$ ''INF file section key
GLOBAL SUCCESS% ''Installation completion code
GLOBAL EXENAME$ ''EXE name
GLOBAL SERIESID$ ''Series ID
GLOBAL INIFILE$ ''.INI filename
GLOBAL MYWINDIR$
GLOBAL MYSYSDIR$
rem Initialize global vriables
rem --------------------------
SETUPPATH$ = "C:\PHI"
SOURCE$ = GetSymbolValue("STF_SRCDIR")
DEST$ = SETUPPATH$
SUCCESS% = INSTALLFAILED
EXTRACOSTS$ = "ExtraCosts"
APPNEEDS$ = "AppNeeds"
SECTIONKEY$ = "SectionKey"
MYSYSDIR$ = GetWindowsSysDir
MYWINDIR$ = GetWindowsDir
FOR i% = 1 TO 26 STEP 1
AddListItem EXTRACOSTS$, "16384"
NEXT i%
rem Get name of localized user interface dialogs
rem --------------------------------------------
CUIDLL$ = "setup.DLL"
rem Subroutines and Functions
rem -------------------------
DECLARE FUNCTION Install AS INTEGER
DECLARE FUNCTION MakePath (szDir$, szFile$) AS STRING
DECLARE FUNCTION GetDLLVersion LIB "setup.dll" (szDLL$) AS INTEGER
DECLARE FUNCTION HideCriticalDirectory LIB "setup.dll" (szDir$) AS INTEGER
DECLARE FUNCTION GetResourceString LIB "setup.dll" (szResource$, idString%) AS INTEGER
DECLARE FUNCTION StartCustomSetup LIB "setup.dll" (hinst%, hwnd%) AS INTEGER
DECLARE FUNCTION StopCustomSetup LIB "setup.dll" (hinst%, hwnd%) AS INTEGER
rem Initialize custom setup logic
rem -----------------------------
SetBitmap CUIDLL$, NOLOGO
i% = GetResourceString (CUIDLL$, STR_TITLE)
SetTitle GetSymbolValue ("ResourceString")
i% = StartCustomSetup (HinstFrame(), HwndFrame ())
i% = SetBeepingMode(1)
rem Make sure that we are running on Windows 3.1 or better
rem ------------------------------------------------------
IF GetWindowsMajorVersion() < 3 THEN
sz$ = UIStartDlg(CUIDLL$, BADWINDOWS, "FInfo0DlgProc", 0, "")
UIPop 1
GOTO CLEANUP
END IF
IF (GetWindowsMajorVersion() = 3) AND (GetWindowsMinorVersion() < 10) THEN
sz$ = UIStartDlg(CUIDLL$, BADWINDOWS, "FInfo0DlgProc", 0, "")
UIPop 1
GOTO CLEANUP
END IF
rem Make sure that we are running on a 386 or better
rem ------------------------------------------------
IF GetWinFlags() AND 2 THEN
sz$ = UIStartDlg(CUIDLL$, BADWINDOWS, "FInfo0DlgProc", 0, "")
UIPop 1
GOTO CLEANUP
END IF
rem Find and read the .INF file.
rem -------------------------------------------------------------------
szInf$ = GetSymbolValue("STF_SRCINFPATH")
IF szInf$ = "" THEN
szTemp$ = GetSymbolValue("STF_SRCDIR")
szInf$ = szTemp$ + "CD.INF"
END IF
ReadInfFile szInf$
rem Which PHI series are we installing?
rem -------------------------------------------------------------------
IF DoesFileExist(MakePath(GetSymbolValue("STF_SRCDIR"), "DEMO.ID"), femExists) = 1 THEN
EXENAME$ = "demo.exe"
SERIESID$ = "Demo"
INIFILE$ = "demo.ini"
ELSEIF DoesFileExist(MakePath(GetSymbolValue("STF_SRCDIR"), "1.ID"), femExists) = 1 THEN
EXENAME$ = "phi1.exe"
SERIESID$ = "#1"
INIFILE$ = "phi1.ini"
ELSEIF DoesFileExist(MakePath(GetSymbolValue("STF_SRCDIR"), "2.ID"), femExists) = 1 THEN
EXENAME$ = "phi2.exe"
SERIESID$ = "#2"
INIFILE$ = "phi2.ini"
ELSEIF DoesFileExist(MakePath(GetSymbolValue("STF_SRCDIR"), "3.ID"), femExists) = 1 THEN
EXENAME$ = "phi3.exe"
SERIESID$ = "#3"
INIFILE$ = "phi3.ini"
ELSEIF DoesFileExist(MakePath(GetSymbolValue("STF_SRCDIR"), "4.ID"), femExists) = 1 THEN
EXENAME$ = "phi4.exe"
SERIESID$ = "#4"
INIFILE$ = "phi4.ini"
END IF
rem Get the destination path; if it's bad, we display an error
rem ----------------------------------------------------------------
GETPATH:
SetSymbolValue "EditTextIn", DEST$
SetSymbolValue "EditFocus", "END"
GETPATHL1:
sz$ = UIStartDlg(CUIDLL$, DESTPATH, "FEditDlgProc", 0, "")
DEST$ = GetSymbolValue("EditTextOut")
IF sz$ = "CONTINUE" THEN
IF IsDirWritable(DEST$) = 0 THEN
GOSUB BADPATH
GOTO GETPATHL1
END IF
IF DoesFileExist(MakePath(DEST$, EXENAME$), femExists) = 1 THEN
i% = GetResourceString (CUIDLL$, STR_MSG1)
szError$ = DEST$ + GetSymbolValue ("ResourceString")
i% = GetDLLVersion(MakePath(DEST$, EXENAME$))
szVersion$ = GetSymbolValue ("VersionString")
szError$ = szError$ + szVersion$
i% = GetResourceString (CUIDLL$, STR_MSG2)
szError$ = szError$ + GetSymbolValue ("ResourceString")
i% = GetResourceString (CUIDLL$, STR_WARNING)
szCaption$ = GetSymbolValue ("ResourceString")
i% = DoMsgBox(szError$, szCaption$, 20)
UIPop 1
IF i% = 7 THEN
GOTO GETPATHL1
END IF
END IF
UIPop 1
ELSEIF sz$ = "REACTIVATE" THEN
GOTO GETPATHL1
ELSE
GOSUB ASKQUIT
GOTO GETPATH
END IF
rem Perform actual installation
rem ---------------------------
INSTALL:
SUCCESS% = Install
IF SUCCESS% = NOSPACE THEN
GOSUB TOOBIG
GOTO GETPATH
END IF
rem When done, issue dialog
rem -----------------------
QUIT:
IF SUCCESS% = INSTALLOK THEN
sz$ = UIStartDlg(CUIDLL$, EXITSUCCESS, "FInfo0DlgProc", 0, "")
ELSE
sz$ = UIStartDlg(CUIDLL$, EXITFAILURE, "FInfo0DlgProc", 0, "")
END IF
UIPop 1
rem Clean up all processing
rem -----------------------
CLEANUP:
i% = StopCustomSetup (HinstFrame(), HwndFrame ())
END
rem ASKQUIT: The user requested quit; does (s)he really want to?
rem ------------------------------------------------------------
ASKQUIT:
sz$ = UIStartDlg(CUIDLL$, EXITQUIT, "FInfoDlgProc", 0, "")
UIPop 1
IF sz$ = "CONTINUE" THEN
RETURN
END IF
GOTO CLEANUP
rem BADPATH: The user entered an invalid destination directory
rem ----------------------------------------------------------
BADPATH:
sz$ = UIStartDlg(CUIDLL$, BADPATH, "FInfo0DlgProc", 0, "")
IF sz$ = "REACTIVATE" THEN
GOTO BADPATH
END IF
UIPop 1
RETURN
rem TOOBIG: The source files won't fit on the requested destination disk
rem --------------------------------------------------------------------
TOOBIG:
sz$ = UIStartDlg(CUIDLL$, TOOBIG, "FInfo0DlgProc", 0, "")
IF sz$ = "REACTIVATE" THEN
GOTO TOOBIG
END IF
UIPop 1
RETURN
rem Install: Perform actual installation
rem ------------------------------------
FUNCTION Install STATIC AS INTEGER
rem Create the destination directory
rem --------------------------------
CreateDir DEST$, cmoNone
rem Build the copy list
rem -------------------
AddSectionFilesToCopyList "Files", SOURCE$, DEST$
AddSectionFilesToCopyList "WINDIR", SOURCE$, MYWINDIR$
AddSectionFilesToCopyList "SYSDIR", SOURCE$, MYSYSDIR$
AddSectionFilesToCopyList "Pictures", SOURCE$, MakePath(DEST$, "pictures")
AddSectionFilesToCopyList "Sounds", SOURCE$, MakePath(DEST$, "sounds")
rem Check that we have enough free space to perform the install
rem -----------------------------------------------------------
ListSym$ = APPNEEDS$
StillNeed& = GetCopyListCost(EXTRACOSTS$, ListSym$, "")
drive$ = MID$(DEST$, 1, 1)
ndrive% = ASC(ucase$(drive$)) - ASC("A") + 1
cost& = VAL(GetListItem(APPNEEDS$, ndrive%))
free& = GetFreeSpaceForDrive(drive$)
IF cost& >= free& THEN
Install = NOSPACE
EXIT FUNCTION
END IF
rem Copy all the files from the source to the destination
rem -----------------------------------------------------
CopyFilesInCopyList
rem Hide critical directories
rem -------------------------
i% = HideCriticalDirectory (MakePath(DEST$, "pictures"))
i% = HideCriticalDirectory (MakePath(DEST$, "sounds"))
rem Update .INI File
rem ----------------
SPLITPATH SOURCE$, drv$, dir$, filename$, ext$
ini$ = MakePath(DEST$, INIFILE$)
RemoveIniKey ini$, "PHI", "Photographer", cmoNone
RemoveIniSection ini$, "Directories", cmoNone
CreateIniKeyValue ini$, "Directories", "Pictures", MakePath(DEST$, "pictures") + "\" , cmoNone
CreateIniKeyValue ini$, "Directories", "Sounds", MakePath(DEST$, "sounds") + "\" , cmoNone
CreateIniKeyValue ini$, "Directories", "Posters", drv$ + "\posters\" , cmoNone
CreateIniKeyValue ini$, "Directories", "Movies", drv$ + "\movies\" , cmoNone
CreateIniKeyValue ini$, "Directories", "Pet0", drv$ + "\movies\pet0\" , cmoNone
CreateIniKeyValue ini$, "Directories", "Pet1", drv$ + "\movies\pet1\" , cmoNone
CreateIniKeyValue ini$, "Directories", "Pet2", drv$ + "\movies\pet2\" , cmoNone
rem Update WIN.INI and SYSTEM.INI
rem -----------------------------
CreateIniKeyValue "WIN.INI", "Extensions", "mov", MakePath(MYWINDIR$,"player.exe") + " ^.mov", cmoOverwrite
CreateIniKeyValue "WIN.INI", "Extensions", "pic", MakePath(MYWINDIR$,"viewer.exe") + " ^.pic", cmoOverwrite
CreateIniKeyValue "WIN.INI", "MCI Extensions", "mov", "QTWVideo", cmoOverwrite
CreateIniKeyValue "WIN.INI", "MCI Extensions", "pic", "QTWVideo", cmoOverwrite
CreateIniKeyValue "WIN.INI", "MCI Extensions", "jpg", "QTWVideo", cmoOverwrite
ini$ = MakePath(MYWINDIR$, "QTW.INI")
CreateIniKeyValue ini$, "QuickTime for Windows", "Implementation", "Full", cmoOverwrite
rem Apple specifies this but it doesn't work - natch
rem i% = WritePrivateProfileString("MCI", "QTWVideo", MakePath(MYSYSDIR$, "mciqtw.drv"), "SYSTEM.INI")
rem Create a Program Manager group
rem ------------------------------
i% = GetResourceString (CUIDLL$, STR_GROUP)
GROUP$ = GetSymbolValue ("ResourceString")
CreateProgmanGroup GROUP$, "", cmoNone
i% = GetResourceString (CUIDLL$, STR_UTILITY)
CreateProgmanItem GROUP$, GetSymbolValue ("ResourceString") + " " + SERIESID$, MakePath(DEST$,EXENAME$), "", cmoOverwrite
i% = GetResourceString (CUIDLL$, STR_README)
CreateProgmanItem GROUP$, GetSymbolValue ("ResourceString"), "write " + MakePath(DEST$,"readme.wri"), "", cmoOverwrite
rem Indicate install completed OK
rem -----------------------------
Install = INSTALLOK
END FUNCTION
rem MakePath: Builds path from directory and file
rem ---------------------------------------------
FUNCTION MakePath (szDir$, szFile$) STATIC AS STRING
IF szDir$ = "" THEN
MakePath = szFile$
ELSEIF szFile$ = "" THEN
MakePath = szDir$
ELSEIF MID$(szDir$, LEN(szDir$), 1) = "\" THEN
MakePath = szDir$ + szFile$
ELSE
MakePath = szDir$ + "\" + szFile$
END IF
END FUNCTION